home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / antdesgn.arc / TLINE.BAS < prev    next >
Encoding:
BASIC Source File  |  1980-01-01  |  6.2 KB  |  184 lines
  1. 10 REM TRANSMISSION LINE DESIGN
  2. 20 REM "ANTENNA DESIGN USING PERSONAL COMPUTERS"
  3. 30 PI=3.141593
  4. 40 KEY OFF
  5. 50 DEF FNLOG10(X)=.4343*LOG(X)
  6. 60 CLS
  7. 70 COLOR 1,0
  8. 80 PRINT "THIS PROGRAM CALCULATES COMMON TRANSMISSION LINE CHARACTERISTICS"
  9. 90 COLOR 4,0
  10. 100 PRINT
  11. 110 PRINT "TRANSMISSION LINES AVAILABLE:"
  12. 120 PRINT "          1-COAXIAL LINE (IMPEDANCE)"
  13. 130 PRINT "          2-TWO WIRE LINE (IMPEDANCE)"
  14. 140 PRINT "          3-MICROSTRIP LINE (IMPEDANCE)"
  15. 150 PRINT "          4-MICROSTRIP LINE (DIMENSIONS)"
  16. 160 PRINT "          5-STRIPLINE (IMPEDANCE)"
  17. 170 PRINT "          6-STRIPLINE (DIMENSIONS)"
  18. 180 PRINT "          7-EXIT PROGRAM"
  19. 190 PRINT
  20. 200 INPUT "WHICH OPTION DO YOU WANT(1 TO 7)";LT
  21. 210 CLS
  22. 220 IF LT=1 THEN GOTO 300
  23. 230 IF LT=2 THEN GOTO 420
  24. 240 IF LT=3 THEN GOTO 550
  25. 250 IF LT=4 THEN GOTO 720
  26. 260 IF LT=5 THEN GOTO 970
  27. 270 IF LT=6 THEN GOTO 1210
  28. 280 IF LT=7 THEN GOTO 1810
  29. 290 GOTO 200
  30. 300 REM COAXIAL LINE
  31. 310 PRINT "COAXIAL LINE DESIGN"
  32. 320 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
  33. 330 INPUT "WHAT IS THE INNER RADIUS(meters)";A
  34. 340 INPUT "WHAT IS THE OUTER RADIUS(meters)";B
  35. 350 Z0=60*LOG(B/A)/SQR(EPS)
  36. 360 COLOR 14,0
  37. 370 PRINT USING "THE CHARACTERISTIC IMPEDANCE IS ###.# ohms";Z0
  38. 380 GOSUB 1470
  39. 390 AC=RS*(1/B+1/A)/(4*PI*Z0)*8.68
  40. 400 AD=OMEGA*EPSDP*377*E0/(2*SQR(EPS))*8.68
  41. 410 GOSUB 1710
  42. 420 REM TWO WIRE LINE
  43. 430 PRINT "TWO-WIRE LINE DESIGN"
  44. 440 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
  45. 450 INPUT "WHAT IS THE CONDUCTOR DIAMETER(meters)";D
  46. 460 INPUT "WHAT IS THE CONDUCTOR SEPARATION(meters)";S
  47. 470 X=S/D
  48. 480 Z0=120*LOG(X+SQR(X*X-1))/SQR(EPS)
  49. 490 COLOR 14,0
  50. 500 PRINT USING "THE CHARACTERISTIC IMPEDANCE IS ###.# ohms";Z0
  51. 510 GOSUB 1470
  52. 520 AC=RS*X/(SQR(X*X-1)*PI*D*Z0)*8.68
  53. 530 AD=OMEGA*EPSDP*377*E0/(2*SQR(EPS))*8.68
  54. 540 GOSUB 1710
  55. 550 REM MICROSTRIP LINE DESIGN
  56. 560 PRINT "MICROSTRIP LINE DESIGN"
  57. 570 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
  58. 580 INPUT "WHAT IS THE SUBSTRATE THICKNESS(meters)";H
  59. 590 INPUT "WHAT IS THE LINE WIDTH(meters)";W
  60. 600 WOH=W/H
  61. 610 IF WOH<=1 THEN EEF=(EPS+1)/2+(EPS-1)/2*(1!/SQR(1+12/WOH)+.04*(1-WOH)^2)
  62. 620 IF WOH>1 THEN EEF=(EPS+1)/2+(EPS-1)/2/SQR(1+12/WOH)
  63. 630 IF WOH<=1 THEN Z0=60*LOG(8/WOH+.25*WOH)/SQR(EEF)
  64. 640 IF WOH>1 THEN Z0=120*PI/(SQR(EEF)*(WOH+1.393+.667*LOG(WOH+1.444)))
  65. 650 COLOR 14,0
  66. 660 PRINT USING "EPSILON EFFECTIVE=##.##";EEF
  67. 670 PRINT USING "THE CHARACTERISTIC IMPEDANCE IS ###.# ohms";Z0
  68. 680 GOSUB 1470
  69. 690 AC=8.68*RS/(Z0*W)
  70. 700 AD=27.3*EPS*(EEF-1)*TAND/(SQR(EEF)*(EPS-1)*L0)
  71. 710 GOSUB 1710
  72. 720 REM MICROSTRIP LINE
  73. 730 PRINT "MICROSTRIP LINE DESIGN"
  74. 740 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
  75. 750 INPUT "WHAT IS THE CHARACTERISTIC IMPEDANCE(ohms)";Z0
  76. 760 A=Z0*SQR(EPS/2+.5)/60+(EPS-1)/(EPS+1)*(.23+.11/EPS)
  77. 770 B=377*PI/(2*Z0*SQR(EPS))
  78. 780 WOH1=8*EXP(A)/(EXP(2*A)-2)
  79. 790 WOH2=2/PI*(B-1-LOG(2*B-1)+(EPS-1)/(2*EPS)*(LOG(B-1)+.39-.61/EPS))
  80. 800 WOH=WOH1
  81. 810 IF WOH2>=2 THEN WOH=WOH2
  82. 820 EEF=(EPS+1)/2+(EPS-1)/2/SQR(1+10/WOH)
  83. 830 COLOR 14,0
  84. 840 PRINT USING "EPSILON EFFECTIVE= ##.##";EEF
  85. 850 PRINT USING "W/H=##.##";WOH
  86. 860 COLOR 4,0
  87. 870 INPUT "ENTER (-1*W) OR (H) (meters)";X
  88. 880 COLOR 14,0
  89. 890 H=X
  90. 900 W=WOH*H
  91. 910 IF X<0 THEN W=-X
  92. 920 IF X<0 THEN H=W/WOH
  93. 930 IF X<0 THEN PRINT USING "THE SUBSTRATE THICKNESS IS ##.##### meters";H
  94. 940 IF X>0 THEN PRINT USING "THE LINE WIDTH IS ##.##### meters";W
  95. 950 GOSUB 1470
  96. 960 GOTO 690
  97. 970 REM STRIPLINE
  98. 980 PRINT "STRIPLINE DESIGN"
  99. 990 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
  100. 1000 INPUT "WHAT IS THE GROUND PLANE SPACING(meters)";B
  101. 1010 INPUT "WHAT IS THE CONDUCTOR WIDTH(meters)";W
  102. 1020 INPUT "WHAT IS THE CONDUCTOR THICKNESS(meters)";T
  103. 1030 WOB=W/B
  104. 1040 TOB=T/B
  105. 1050 WEOB=WOB
  106. 1060 IF W/(B-T)<.35 THEN WEOB=WEOB-(.35-WEOB)^2/(1+12*TOB)
  107. 1070 IF TOB=0 THEN CF=1.386
  108. 1080 IF TOB>0 THEN CF=2*LOG(1/(1-TOB)+1)-TOB*LOG(1/(1-TOB)^2-1)
  109. 1090 Z0=30*PI*(1-TOB)/(SQR(EPS)*(WEOB+CF/PI))
  110. 1100 COLOR 14,0
  111. 1110 PRINT USING "THE CHARACTERISTIC IMPEDANCE IS ###.# ohms";Z0
  112. 1120 GOSUB 1470
  113. 1130 IF T=0 THEN T=W/1000
  114. 1140 ZB=Z0*SQR(EPS)*(1+2.3*TOB)
  115. 1150 AA=1+2*W/(B-T)+(B+T)/(PI*(B-T))*LOG((2*B-T)/T)
  116. 1160 BB=(.35-WOB)*(TOB*(17.45*B+35*W)-9*W+5.85-32.4*TOB*T)/(B-T)/(1+12*TOB)^2
  117. 1170 IF ZB<120 THEN BB=0
  118. 1180 AC=.0231*RS*EPS*Z0*(AA+BB)/(30*PI*(B-T))
  119. 1190 AD=27.3*SQR(EPS)*TAND/L0
  120. 1200 GOSUB 1710
  121. 1210 REM STRIPLINE DESIGN
  122. 1220 PRINT "STRIPLINE DESIGN"
  123. 1230 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
  124. 1240 INPUT "WHAT IS THE CHARACTERISTIC IMPEDANCE(ohms)";Z0
  125. 1250 INPUT "WHAT IS THE STRIP THCK/GRND. PLANE SPACING RATIO";TOB
  126. 1260 ZB=Z0*SQR(EPS)*(1+2.3*TOB)
  127. 1270 CF=1.386
  128. 1280 IF TOB>0 THEN CF=2*LOG(1/(1-TOB)+1)-TOB*LOG(1/(1-TOB)^2-1)
  129. 1290 X=30*PI*(1-TOB)/(Z0*SQR(EPS))-CF/PI
  130. 1300 IF ZB>120 THEN WOB=(6*TOB+.85)-SQR((6*TOB+.85)^2-X*(12*TOB+1)-.1225)
  131. 1310 IF ZB<120 THEN WOB=X
  132. 1320 COLOR 14,0
  133. 1330 PRINT USING"W/B=##.##";WOB
  134. 1340 COLOR 4,0
  135. 1350 INPUT "ENTER (-1*W) OR (B) (meters)";X
  136. 1360 COLOR 14,0
  137. 1370 B=X
  138. 1380 W=WOB*B
  139. 1390 IF X<0 THEN W=-X
  140. 1400 IF X<0 THEN B=W/WOB
  141. 1410 IF X<0 THEN PRINT USING "THE GROUND PLANE SPACING IS ##.#### meters";B
  142. 1420 IF X>0 THEN PRINT USING "THE LINE WIDTH IS ##.#### meters";W
  143. 1430 T=TOB*B
  144. 1440 GOSUB 1470
  145. 1450 GOTO 1130
  146. 1460 END
  147. 1470 REM ATTENUATION DATA
  148. 1480 PRINT
  149. 1490 COLOR 4,0
  150. 1500 INPUT "DO YOU WANT TO CALCULATE ATTENUATION(Y,N)";AT$
  151. 1510 IF AT$="N" THEN GOTO 1760
  152. 1520 INPUT "WHAT IS THE FREQUENCY(MHz)";FMC
  153. 1530 INPUT "WHAT IS THE DIELECTRIC LOSS TANGENT";TAND
  154. 1540 PRINT "WHAT IS THE CONDUCTOR MATERIAL:"
  155. 1550 PRINT "          1-GOLD"
  156. 1560 PRINT "          2-SILVER"
  157. 1570 PRINT "          3-COPPER"
  158. 1580 PRINT "          4-OTHER"
  159. 1590 INPUT "ENTER 1-4";CM
  160. 1600 IF CM<1 OR CM>4 THEN GOTO 1590
  161. 1610 IF CM=1 THEN SIG=4.1E+07
  162. 1620 IF CM=2 THEN SIG=6.17E+07
  163. 1630 IF CM=3 THEN SIG=5.8E+07
  164. 1640 IF CM=4 THEN INPUT "WHAT IS THE CONDUCTIVITY(mhos/meter)";SIG
  165. 1650 OMEGA=2*PI*FMC*1000000!
  166. 1660 RS=SQR(PI*FMC*1000000!*.0000004*PI/SIG)
  167. 1670 EPSDP=EPS*TAND
  168. 1680 E0=8.85E-12
  169. 1690 L0=300/FMC
  170. 1700 RETURN
  171. 1710 REM PRINT ATTENUATION
  172. 1720 COLOR 14,0
  173. 1730 PRINT USING "ATTEN. DUE TO CONDUCTOR =##.#### dB/meter";AC
  174. 1740 PRINT USING "ATTEN. DUE TO DIELECTRIC=##.#### dB/meter";AD
  175. 1750 PRINT USING "TOTAL ATTEN.            =##.#### dB/meter";AD+AC
  176. 1760 PRINT
  177. 1770 COLOR 4,0
  178. 1780 INPUT "CONTINUE(Y,N)";IS$
  179. 1790 IF IS$="N" THEN GOTO 1810
  180. 1800 GOTO 60
  181. 1810 COLOR 7,0
  182. 1820 KEY ON
  183. 1830 END
  184.